このセクションの記事

本記事では、ソアスクv3.1より追加された分析オブジェクトのレコードを利用して組織の

  • 平均チャーンMRR
  • 平均チャーンレート

の月ごとの推移をダッシュボードでグラフ表示するための手順をご紹介します。

※v3.1以降のソアスクでのみ、本記事で紹介するレポート・ダッシュボードは作成可能です。

 

分析・分析明細オブジェクトの各項目についての説明や、どのデータを基に分析・分析明細レコードが作成されるかについては、以下の記事で説明しておりますので、本記事では割愛します。
本記事と併せてご参照ください。

v3.1から追加されたサブスクリプション分析機能の使用方法

 

レポート・ダッシュボードはSalesforceの標準機能です。
詳しくは、以下の公式ヘルプページをご参照ください。

レポートとダッシュボード

 

用語説明

  • MRR
    Monthly Recurring Revenueの略称で、月ごとに繰り返し得られる収益を表します。
    新規獲得やアップセル（上位サービスへの変更など）で増加し、解約やダウンセル（下位サービスへの変更など）で減少します。
  • チャーンMRR
    解約/ダウンセルでの減少分のみを加味した、前月のMRRと比べたときの今月のMRRの減額分の絶対値です。
  • 平均チャーンMRR
    直近1年間のチャーンMRRの合計÷12 で算出されます。
    2020年12月の場合は「2020年1月～12月のチャーンMRRの合計÷12」です。
  • 平均チャーンレート
    直近1年間の各月のチャーンレートの合計÷12 で算出されます。
    ※各月のチャーンレートは「当月のチャーンMRR÷前月末時点でのMRR」で算出されます。

 

作成するレポート・ダッシュボードの概要

レポート

分析レコードを月ごとに集計し、月の契約金額合計、前月との差分金額、過去12か月の平均チャーンMRR、過去12か月の平均チャーンレートを表示するレポートを作成します。

report_appearance.PNG

レポートで使用する集計関数の使い方について以下記事で紹介していますので、興味のある方・理解を深めたい方は是非ご参照ください。

サブスクリプション分析のレポートで使用するPREVGROUPVAL関数の説明

 

ダッシュボード

作成するレポートを基に、2つのコンポーネントを作成します。

  1. 平均チャーンMRRの月推移を表示するコンポーネント
    dashboard_component_1.PNG
  2. 平均チャーンレートの月推移を表示するコンポーネント
    dashboard_component_2.PNG

 

レポート作成手順

  1. 「レポート」タブを開いて、右上の「新規レポート」をクリックします。
    report_step1.png
  2. レポートタイプに「分析」を選択し、「続行」をクリックします。
    report_step2.png
  3. 以下項目を列に追加します。
    • 分析: 分析番号
    • 契約金額
    • 金額差分
  4. 「計上日」項目でグルーピングします。
    report_step3_4.png
  5. プレビューを更新し、計上日の列の「▼」をクリックします。
    集計期間単位に「年月」を指定します。
    select_yearmonth_as_groupingunit.png
  6. 検索条件には
    • 種別 = 月次
    • 見込み / 実績 = 実績
    を指定します。
    report_search_condition.png
  7. 行レベルの数式「減額」を用意します。
    • add_row_level_formula.PNG
    • row_level_formula_detail.png
    • 数式は以下を使用します。
      ※金額差分の値と0のうち小さい方を返すことで、新規契約やアップセルによる増額を計算対象から外しています。
      ※先頭に「-」を付けることで、減額（負の値）の絶対値を返します。 
      -MIN(appsfs__Analysis__c.appsfs__fs_AmountDifference__c, 0)
  8. 「平均チャーンMRR」「平均チャーンレート」の2つの集計項目を作成します。

    ※集計項目の作成方法の詳細については以下ヘルプページをご参照ください。
    集計項目を使用したグループと合計の評価
    ※集計項目の数式では、直近12ヶ月の各月毎に契約金額・減額の合計値を算出するため、レポート関数「PREVGROUPVAL」を使用します。
    PREVGROUPVALの挙動については以下ヘルプページをご参照ください。
    PARENTGROUPVAL および PREVGROUPVAL

    create_formula_button.png

    平均チャーンMRR
    • 以下のように設定します。
      report_step_8_churn_ave_general.PNGreport_step_8_churn_ave_display.PNG
    • 入力する数式は以下です。
      この数式で「直近1年間のチャーンMRRの合計÷12」を算出します。
      ※数式内の「CDF1」は作成した行レベルの数式「減額」を表します。
    • (
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        0
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        1
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        2
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        3
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        4
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        5
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        6
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        7
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        8
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        9
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        10
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c,
        11
    )
) / 12

    平均チャーンレート
    • 以下のように設定します。
      report_step_8_churn_rate_general.PNGreport_step_8_churn_rate_display.PNG
    • 入力する数式は以下です。
      この数式で「直近1年間の各月のチャーンレートの合計÷12」を算出します。
      ※各月のチャーンレート = 当月のチャーンMRR÷前月末時点でのMRR
      ※数式内の「CDF1」は作成した行レベルの数式「減額」を表します。
    • (
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        0
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        1
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        1
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        2
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        2
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        3
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        3
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        4
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        4
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        5
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        5
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        6
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        6
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        7
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        7
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        8
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        8
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        9
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        9
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        10
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        10
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        11
    )
    +
    PREVGROUPVAL(
        CDF1:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        11
    )
    /
    PREVGROUPVAL(
        appsfs__Analysis__c.appsfs__fs_ContractAmount__c:SUM, 
        appsfs__Analysis__c.appsfs__fs_RecordDate__c, 
        12
    )
) / 12
  9. 右上の「保存＆実行」をクリックします。
    report_step6.png
  10. レポート名、レポートの一意の名前を入力します。
    レポートの説明入力とフォルダの指定はお好みで行い、「保存」をクリックします。
    save_report.png

 

ダッシュボード作成手順

  1. 「ダッシュボード」タブを開いて、右上の「新規ダッシュボード」ボタンをクリックします。
    new_dashboard.png
  2. ダッシュボード名を入力して、「作成」をクリックします。
    create_new_dashboard_button.png

 

平均チャーンMRRの推移を表示するコンポーネントを設置

  1. 「＋コンポーネント」をクリックします。
    dashboard_step_1.PNG
  2. 使用するレポートを選択します。
    dashboard_step_2.PNG
  3. 表示グラフに「縦棒グラフ」を指定します。
    dashboard_mrr_ave_step3.PNG
  4. X軸は「計上日」Y軸は「平均チャーンMRR」を選択します。
    dashboard_churn_ave_step_4.PNG
  5. 並び替えは「計上日」の昇順とします。
    dashboard_churn_ave_step_5.PNG
  6. 他の値はお好みで設定し、「追加」をクリックします。
    dashboard_churn_ave_step_6.PNG

平均チャーンレートの推移を表示するコンポーネントを設置

  1. 「＋コンポーネント」をクリックします。
    dashboard_step_1.PNG
  2. 使用するレポートを選択します。
    dashboard_step_2.PNG
  3. 表示グラフに「折れ線グラフ」を指定します。
    dashboard_churn_rate_step_3.PNG
  4. X軸は「計上日」Y軸は「平均チャーンレート」を選択します。
    ※「値を表示」のチェックは外しています。
    dashboard_churn_rate_step_4.PNG
  5. 並び替えは「計上日」の昇順とします。
    dashboard_churn_rate_step_5.PNG
  6. 他の値はお好みで設定し、「追加」をクリックします。
    dashboard_churn_rate_step_6.PNG

最後に、各コンポーネントのサイズを調節して、右上の「保存」をクリックします。
※このとき表示される内容は実際のデータとはずれることがあります。

save_dashboard.png

 

完成したダッシュボードの見た目は、以下のようになります。

dashboard_appearance.PNG

 

おわりに

ソアスクv3の分析・分析明細レコードは、レポートやダッシュボードで見やすくまとめることでその真価を発揮します。

お好みの分析データ表示設定を行う際に、本記事が参考になれば幸いです。

 

関連記事